***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar 15, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P6SMB100A A K 
.param
+vc0 = 5.246e-9		vc1 = 3.816e-10		vc2 = 1.000e0		vc3 = 2.413e-10		vc4 = 5.655e-2
+tc1 = 4.018e-2		tc2 = 3.245e-2		tc3 = 5.208e-3		tc4 = 4.095e-3
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1        
***** dc model parameter *****
+ is = 1.626e-11	   n = 1.202		  rs = 2.053e-2
+ibv = 1e-3		 nbv = 1		  bv = 100
+ikf = 2.956e-2
***** capacitance parameter *****
+cjo = 4.501e-10	   m = 3.382e-1		  vj = 5.412e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.034		 xti = 3
+trs1 = 6.005e-5	trs2 = 1.206e-6		tikf = -5e-5
+tbv1 = 0.7797e-3	tbv2 = -0.2212e-6
.ends P6SMB100A
*$
